.files/nix/homeModules/common/fish/default.nix

{
  lib,
  pkgs,
  ...
}: {
  imports = [
    ./aliasesAbbrs.nix
  ];

  #
  # Script dependencies
  #
  home.packages = [pkgs.vivid];
  programs = {
    fd.enable = true;
    fzf.enable = true;
  };

  #
  # Integration
  #
  home.shell.enableFishIntegration = true;

  #
  # Scripts and functions
  #
  xdg.configFile =
    lib.mapAttrs'
    (path: _:
      lib.nameValuePair "fish/functions/${path}" {source = "${./functions}/${path}";})
    (builtins.readDir ./functions);

  programs.fish = {
    interactiveShellInit = builtins.readFile ./shellInit.fish;

    plugins = [
      {
        name = "fzf-fish";
        src = pkgs.fetchFromGitHub {
          owner = "PatrickF1";
          repo = "fzf.fish";
          rev = "v10.3";
          hash = "sha256-T8KYLA/r/gOKvAivKRoeqIwE2pINlxFQtZJHpOy9GMM=";
        };
      }
      {
        name = "sponge";
        src = pkgs.fetchFromGitHub {
          owner = "meaningful-ooo";
          repo = "sponge";
          sha256 = "sha256-MdcZUDRtNJdiyo2l9o5ma7nAX84xEJbGFhAVhK+Zm1w=";
          rev = "1.1.0";
        };
      }
    ];
  };
}