# Entry point to cherry pick modules
let
  sources = import ../sources.nix;

  hostname = "tungsten";
  username = "leana";
in
  {lib, ...}: let
    inherit (lib.modules) mkAliasOptionModule;
  in {
    imports = [
      #
      # Shorthands
      #
      (mkAliasOptionModule ["me"] ["users" "users" username])

      #
      # hostname
      #
      {_module.args = {inherit hostname;};}

      #
      # nixpkgs
      #
      {
        nixpkgs = {
          overlays = map import [
            ../overlays/agenix.nix
            ../overlays/disko.nix
            ../overlays/nur.nix
            ../overlays/wired-notify.nix
            ../overlays/nix-tree.nix

            ../packages/overlay.nix
          ];

          # Set NIX_PATH and flake registry at the same time
          # https://github.com/NixOS/nixpkgs/pull/254405
          flake.source = sources.nixpkgs;
        };

        system.nixos.version = lib.substring 0 8 sources.nixpkgs.revision;
      }

      #
      # NixOS modules
      #
      ./tungsten/nixos/hardware-configuration.nix # generated
      {
        users.users.root.openssh.authorizedKeys.keys = let
          ids = import ../identities.nix;
        in
          builtins.concatMap builtins.attrValues (builtins.attrValues ids);
      }

      ./tungsten/nixos/misc.nix

      ./tungsten/nixos/locale.nix
      ./tungsten/nixos/unfree-predicate.nix

      ../nixosModules/common/disable-command-not-found.nix
      ../nixosModules/common/network.nix
      ../nixosModules/common/sudo-conf.nix
      ../nixosModules/common/system-nixconf.nix

      ../nixosModules/extra/layouts
      ../nixosModules/extra/leana.nix

      ../nixosModules/extra/macbook-swap-fn-ctrl.nix
      ../nixosModules/extra/macbook-swap-cmd-opt.nix

      #
      # Extern modules
      #
      (sources.disko + "/module.nix")
      ../disko/tungsten/btrfs.nix

      (sources.nixos-hardware + "/apple/macbook-air/6")
    ];
  }