let
  sources = import ../sources.nix;

  hostname = "vm";
  username = "leana";
in
  {
    config,
    lib,
    ...
  }: let
    inherit (lib.modules) mkAliasOptionModule;
  in {
    imports = [
      #
      # Shorthands
      #
      (mkAliasOptionModule ["me"] ["users" "users" username])
      (mkAliasOptionModule ["hm"] ["home-manager" "users" username])

      #
      # hostname
      #
      {_module.args = {inherit hostname;};}

      #
      # nixpkgs
      #
      {
        nixpkgs = {
          overlays = map import [
            ../overlays/agenix.nix
            ../overlays/disko.nix
            ../overlays/nur.nix
            ../overlays/wired-notify.nix
            ../overlays/nix-tree.nix
            ../overlays/wallpapers.nix

            ../overlays/packages.nix
            ./vanadium/overlay.nix
          ];

          # Set NIX_PATH and flake registry at the same time
          # https://github.com/NixOS/nixpkgs/pull/254405
          flake.source = sources.nixpkgs;
        };

        system.nixos.version = lib.substring 0 8 sources.nixpkgs.rev;
      }

      #
      # NixOS modules
      #
      ./vanadium/nixos/gui.nix

      ./vanadium/nixos/locale.nix
      ./vanadium/nixos/unfree-predicate.nix

      ../nixosModules/extra/layouts
      ../nixosModules/extra/leana.nix

      (import (sources.lix-module + "/module.nix") {lix = sources.lix;})

      #
      # home-manager
      #
      (sources.home-manager + "/nixos")
      {
        home-manager = {
          useGlobalPkgs = true;
          useUserPackages = true;
          sharedModules = [{home.stateVersion = lib.mkDefault config.system.stateVersion;}];
        };

        hm.imports = [
          #
          # hostname
          #
          {_module.args = {inherit hostname;};}

          #
          # home modules
          #
          ./vanadium/home/misc.nix

          ./vanadium/home/firefox.nix
          ./vanadium/home/xmobar.nix
        ];
      }

      {
        # VM specifics
        users.mutableUsers = false;
        me.password = "";
      }
    ];
  }