{
  python3,
  fetchFromGitHub,
  lib,
}:
python3.pkgs.buildPythonApplication {
  pname = "webtoon_downloader";
  version = "2.0.0";

  pyproject = true;
  src =
    # Don't use fetchPypi because it doesn't have tests
    # Fetching the source from GitHub works better
    fetchFromGitHub {
      owner = "Zehina";
      repo = "Webtoon-Downloader";
      rev = "f6c4ea949db4e48b0139664a9c33120fb3a2a6b2";
      hash = "sha256-jbxSXlM6uuROrxV0v6pd3eGnupp5AXQMpflQ2QnrekI=";
    };

  build-system = with python3.pkgs; [
    poetry-core
  ];

  dependencies = with python3.pkgs; [
    aiofiles
    beautifulsoup4
    furl
    httpx
    h2
    lxml
    pillow
    pymupdf
    rich
    rich-click
    typing-extensions
  ];

  pythonRelaxDeps = [
    "aiofiles"
    "httpx"
    "lxml"
    "pillow"
    "rich"
  ];

  pythonImportsCheck = [ "webtoon_downloader" ];

  nativeCheckInputs = with python3.pkgs; [
    pytestCheckHook
    pytest-asyncio
  ];

  disabledTestPaths = [
    "tests/test_extractors.py" # requires network
  ];

  meta = {
    description = "Webtoons Scraper able to download all chapters of any series wanted";
    homepage = "https://github.com/Zehina/Webtoon-Downloader";
    license = lib.licenses.mit;
    mainProgram = "webtoon-downloader";
  };
}