let
  sources = import ../../sources.nix;
  lib = import (sources.nixpkgs + "/lib");

  infuse-lib = import sources.infuse {
    inherit lib;
    sugars = infuse-lib.v1.default-sugars;
  };

  infuse = lib.flip infuse-lib.v1.infuse;
in
  # Why shouldn't I go crazy with overlays?
  final:
    infuse {
      cmus.__input.alsaSupport = _: false;

      fish.__input.usePython = _: false;

      tmux.__input.withSixel = _: false;

      ranger.__input.imagePreviewSupport = _: false;
      ranger.__input.sixelPreviewSupport = _: false;

      vlc.__input.chromecastSupport = _: false;
      vlc.__input.waylandSupport = _: false;

      # I don't really use helix, but it's nice to have the W alias just in case
      helix.__output.patches.__append = [
        ./patches/helix/W-as-write.patch
      ];

      # Too loud
      alejandra.__output.patches.__append = [
        ./patches/alejandra/no-ads.patch
      ];
      alejandra.__output.doCheck = _: false;

      fcitx5.__output.cmakeFlags.__append = [
        (lib.cmakeFeature "ENABLE_EMOJI" "Off")
        (lib.cmakeFeature "ENABLE_WAYLAND" "Off")
      ];
      fcitx5.__output.patches.__append = [
        ./patches/fcitx5/disable-clipboard.patch
        ./patches/fcitx5/disable-quickphrase.patch
        ./patches/fcitx5/disable-unicode.patch
      ];
      fcitx5-chinese-addons.__output.cmakeFlags.__append = [
        (lib.cmakeFeature "ENABLE_BROWSER" "Off")
        (lib.cmakeFeature "ENABLE_CLOUDPINYIN" "Off")
        (lib.cmakeFeature "ENABLE_DATA" "Off")
      ];
      fcitx5-chinese-addons.__output.patches.__append = [
        ./patches/fcitx5-chinese-addons/disable-chttrans.patch
        ./patches/fcitx5-chinese-addons/disable-fullwidth.patch
        # Note: disabling pinyin helper breaks canjie
      ];

      # TODO: remove this when upstream is updated
      sudo.__output.patches.__append = [
        (final.fetchpatch {
          name = "CVE-2025-32462";
          url = "https://github.com/sudo-project/sudo/commit/d530367828e3713d09489872743eb92d31fb11ff.patch";
          hash = "sha256-mS8fcPV1QDv9SDuGN7dfDLtVLSBP+apotYW1UsEBPvU=";
        })
        (final.fetchpatch {
          name = "CVE-2025-32463";
          url = "https://github.com/sudo-project/sudo/commit/fdafc2ceb36382b07e604c0f39903d56bef54016.patch";
          hash = "sha256-4FP8z5pKwcOfJxjJ9X/IbCgriKJm1H/HnswuvYjBlt8=";
        })
      ];
    }