let
  sources = import ../../../npins;
  lib = import (sources.nixpkgs + "/lib");

  infuse-lib = import sources.infuse {
    inherit lib;
    sugars = infuse-lib.v1.default-sugars;
  };

  infuse = lib.flip infuse-lib.v1.infuse;
in
# Why shouldn't I go crazy with overlays?
final:
infuse {
  cmus.__input.alsaSupport = _: false;

  fish.__input.usePython = _: false;

  tmux.__input.withSixel = _: false;

  vlc.__input.chromecastSupport = _: false;
  vlc.__input.waylandSupport = _: false;

  # I don't really use helix, but it's nice to have the W alias just in case
  helix.__output.patches.__append = [
    ./patches/helix/W-as-write.patch
  ];

  # Too loud
  alejandra.__output.patches.__append = [
    ./patches/alejandra/no-ads.patch
  ];
  alejandra.__output.doCheck = _: false;

  # TODO:
  # pinned branch of https://github.com/astrand/xclip/tree/xerror
  # use this until #43 gets resolved properly
  xclip.__output.src =
    _:
    final.fetchFromGitHub {
      owner = "astrand";
      repo = "xclip";
      rev = "2c3b811002b35d3be7f39cc1145dd06bdb32e31c";
      hash = "sha256-hHbq97GTKiRw8LZa/LY4LUOFOd/5H4+S+NR0BJfcu6M=";
    };

  fcitx5.__output.cmakeFlags.__append = [
    (lib.cmakeFeature "ENABLE_EMOJI" "Off")
    (lib.cmakeFeature "ENABLE_WAYLAND" "Off")
  ];
  fcitx5.__output.patches.__append = [
    ./patches/fcitx5/disable-clipboard.patch
    ./patches/fcitx5/disable-quickphrase.patch
    ./patches/fcitx5/disable-unicode.patch
  ];
  fcitx5-chinese-addons.__output.cmakeFlags.__append = [
    (lib.cmakeFeature "ENABLE_BROWSER" "Off")
    (lib.cmakeFeature "ENABLE_CLOUDPINYIN" "Off")
    (lib.cmakeFeature "ENABLE_DATA" "Off")
  ];
  fcitx5-chinese-addons.__output.patches.__append = [
    ./patches/fcitx5-chinese-addons/disable-chttrans.patch
    ./patches/fcitx5-chinese-addons/disable-fullwidth.patch
    # Note: disabling pinyin helper breaks canjie
  ];

  # Security, Xorg vuln
  # Backport has failed in upstream currently <https://github.com/NixOS/nixpkgs/pull/457804>,
  # might as well patch it while people are blogging about it <https://github.com/Xe/site/pull/1062>
  # Upstream talks about it here https://lists.x.org/archives/xorg-announce/2025-October/003635.html
  xorg.xorgserver.__output.version =
    oldVersion:
    let
      version = "21.1.20";
    in
    if oldVersion == version then throw "This patch has been merged upstream" else version;
  xorg.xorgserver.__output.src =
    _:
    final.fetchurl {
      url = "mirror://xorg/individual/xserver/xorg-server-21.1.20.tar.xz";
      sha256 = "sha256-dpW8YYJLOoG2utL3iwVADKAVAD3kAtGzIhFxBbcC6Tc=";
    };
}