let
  sources = import ../../sources.nix;
  lib = import (sources.nixpkgs + "/lib");

  infuse-lib = import sources.infuse {
    inherit lib;
    sugars = infuse-lib.v1.default-sugars;
  };

  infuse = lib.flip infuse-lib.v1.infuse;
in
  # Why shouldn't I go crazy with overlays?
  (final: infuse {
    cmus.__input.alsaSupport = _: false;

    fish.__input.usePython = _: false;

    tmux.__input.withSixel = _: false;

    ranger.__input.imagePreviewSupport = _: false;
    ranger.__input.sixelPreviewSupport = _: false;

    vlc.__input.chromecastSupport = _: false;
    vlc.__input.waylandSupport = _: false;

    fcitx5.__output.cmakeFlags.__append = [
      (lib.cmakeFeature "ENABLE_EMOJI" "Off")
      (lib.cmakeFeature "ENABLE_WAYLAND" "Off")
    ];
    fcitx5.__output.patches.__append = [
      ./patches/fcitx5/disable-clipboard.patch
      ./patches/fcitx5/disable-quickphrase.patch
      ./patches/fcitx5/disable-unicode.patch
    ];
    fcitx5-chinese-addons.__output.cmakeFlags.__append = [
      (lib.cmakeFeature "ENABLE_BROWSER" "Off")
      (lib.cmakeFeature "ENABLE_CLOUDPINYIN" "Off")
      (lib.cmakeFeature "ENABLE_DATA" "Off")
    ];
    fcitx5-chinese-addons.__output.patches.__append = [
      ./patches/fcitx5-chinese-addons/disable-chttrans.patch
      ./patches/fcitx5-chinese-addons/disable-fullwidth.patch
      # Note: disabling pinyin helper breaks canjie
    ];
    fcitx5-table-extra.__output.src = _: final.fetchFromGitHub {
      owner = "leana8959";
      repo = "fcitx5-table-extra";
      rev = "3fb844280a5154389be17e422a98ad89cafccc38";
      hash = "sha256-8iGNQYQH8tT3p6VedVBgfxHqXVLkFEiDEd1H7CBFXqg=";
      fetchSubmodules = true;
    };
    fcitx5-table-extra.__output.nativeBuildInputs.__append = [ final.python3 ];
    fcitx5-table-extra.__output.preConfigure.__prepend = ''
      python3 ./generate.py
    '';
  })