let
  sources = import ../../npins;
in
  {pkgs ? import sources.pin-masna3shell {}}:
    pkgs.mkShell (let
      libs = with pkgs; [
        zlib
        libpq
        libsodium
      ];

      hlib = pkgs.haskell.lib;

      callHackage = {
        name,
        version,
        haskellPackages ? pkgs.haskellPackages,
      }: let
        pkg = haskellPackages.callHackage name version {};
      in
        hlib.dontCheck (hlib.doJailbreak pkg);

      haskellPackages = pkgs.haskell.packages.ghc910;
    in {
      name = "masna3";
      packages =
        [
          pkgs.haskell.packages.ghc9102.ghc
          pkgs.haskell.packages.ghc9102.haskell-language-server

          haskellPackages.cabal-install
          haskellPackages.postgresql-migration
          (callHackage {
            name = "fourmolu";
            version = "0.18.0.0";
            haskellPackages = pkgs.haskell.packages.ghc912;
          })
          (callHackage {
            name = "hlint";
            version = "3.10";
            haskellPackages = pkgs.haskell.packages.ghc912;
          })
          pkgs.haskell.packages.ghc98.apply-refact
          haskellPackages.ghc-tags
          haskellPackages.cabal-gild

          pkgs.gnumake
          pkgs.pkg-config
        ]
        ++ libs;

      LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath libs;
    })