let
  bootpkgs = import <nixpkgs> {};

  pkgs = import (bootpkgs.fetchFromGitHub {
    owner = "NixOS";
    repo = "nixpkgs";
    rev = "nixos-25.05";
    hash = "sha256-eogqv6FqZXHgqrbZzHnq43GalnRbLTkbBbFtEfm1RSc=";
  }) {};

  unstable = import (bootpkgs.fetchFromGitHub {
    owner = "NixOS";
    repo = "nixpkgs";
    rev = "haskell-updates";
    hash = "sha256-dwgA4RwZhqiz4VZoCBf9Li8hWIppGEhcIRL/PIBsStU=";
  }) {};
in
  pkgs.mkShell (let
    libs = with pkgs; [
      zlib
      libpq
      libsodium
    ];

    hlib = pkgs.haskell.lib;

    callHackage = {
      name,
      version,
      haskellPackages ? pkgs.haskellPackages,
    }: let
      pkg = haskellPackages.callHackage name version {};
    in
      hlib.dontCheck (hlib.doJailbreak pkg);

    haskellPackages = pkgs.haskellPackages;
  in {
    name = "masna3";
    packages =
      [
        # used pinned ghc
        unstable.haskell.packages.ghc9102.ghc

        # Broken :(
        # unstableHaskellPackages.haskell-language-server

        haskellPackages.cabal-install
        haskellPackages.postgresql-migration
        (callHackage {
          name = "fourmolu";
          version = "0.18.0.0";
          haskellPackages = pkgs.haskell.packages.ghc912;
        })
        (callHackage {
          name = "hlint";
          version = "3.10";
          haskellPackages = pkgs.haskell.packages.ghc912;
        })
        haskellPackages.apply-refact
        haskellPackages.ghc-tags
        haskellPackages.cabal-gild

        pkgs.gnumake
        pkgs.pkg-config
      ]
      ++ libs;

    LD_LIBRARY_PATH = pkgs.lib.makeLibraryPath libs;
  })