nix: refactor modules pass 2

2025-12-06 22:59:15 +00:00 · 2025-04-01 21:40:43 +02:00 · 2025-04-01 21:40:43 +02:00 · 1716faf2cd
commit 1716faf2cd
parent ec7246e524
19 changed files with 11 additions and 11 deletions
--- a/nix/configurations/vanadium/home/default.nix
+++ b/nix/configurations/vanadium/home/default.nix
@ -0,0 +1,127 @@
+{
+  pkgs,
+  lib,
+  nixosConfig ? {},
+  config,
+  ...
+}: let
+  inherit (pkgs) myPkgs;
+in {
+  imports = [
+    ./firefox.nix
+    ./gui.nix
+    ./xmobar.nix
+
+    # Language server packages, etc
+    ./dev.nix
+  ];
+
+  home.file = {
+    ".xscreensaver".source = "${./xscreensaver/.xscreensaver}";
+    ".wallpaper".source = "${pkgs.wallpapers.estradiol}/main.svg";
+  };
+
+  home.packages = [
+    pkgs.zip
+    pkgs.unzip
+    pkgs.gnutar
+    pkgs.p7zip
+    pkgs.bc
+    pkgs.dig
+    myPkgs.hutils
+    pkgs.miniserve
+    pkgs.agenix
+
+    # pdf utilities
+    pkgs.poppler_utils # pdfseparate, pdfunite
+    myPkgs.easyscan
+
+    # productivity / media
+    pkgs.evolution
+    pkgs.libreoffice
+    pkgs.iamb
+    pkgs.calibre
+    pkgs.rawtherapee
+    pkgs.digikam
+    pkgs.gimp
+    pkgs.vlc
+    pkgs.nautilus
+    pkgs.sushi # space bar previewer
+    pkgs.blender
+    pkgs.inkscape
+
+    # wm utilities
+    myPkgs.xbrightness
+    pkgs.dmenu
+    pkgs.xclip
+    pkgs.playerctl # talk to playerctld
+    pkgs.hacksaw
+    pkgs.shotgun
+    pkgs.xscreensaver # talk to xscreensaver
+    pkgs.xcolor
+    pkgs.boomer
+
+    # audio utilities
+    pkgs.helvum
+    pkgs.pavucontrol
+
+    # fun
+    myPkgs.prop-solveur
+    myPkgs.hbf
+    pkgs.lucky-commit
+  ];
+
+  age.secrets = {
+    sshconfig = {
+      file = "${../../../secrets/sshconfig.age}";
+      path = "/home/leana/.ssh/config";
+    };
+    ltex_dict = {
+      file = "${../../../secrets/ltex_dict.age}";
+      path = "/home/leana/.config/ltex_dict";
+    };
+  };
+
+  programs = {
+    kitty.enable = true;
+    password-store.enable = true;
+    feh.enable = true;
+    sioyek.enable = true;
+    cmus.enable = true;
+    ranger.enable = true;
+    xmobar.enable = true;
+
+    # ROCm support is needed for AMD GPU
+    # https://github.com/aristocratos/btop?tab=readme-ov-file#gpu-compatibility
+    btop.package = pkgs.btop-rocm;
+
+    neovim.defaultEditor = true;
+  };
+
+  services.wired.enable = true;
+  services.playerctld.enable = true;
+
+  # Disable the blueman pop up persistently
+  # https://github.com/blueman-project/blueman/issues/1556#issuecomment-882857426
+  dconf.settings."org/blueman/general" = let
+    isBlueman = p: lib.hasInfix "blueman" (lib.getName p);
+  in
+    lib.mkIf
+    (builtins.any isBlueman (nixosConfig.environment.systemPackages or [])
+      || builtins.any isBlueman config.home.packages)
+    {
+      plugin-list = ["!ConnectionNotifier"];
+    };
+
+  services.battery-notify = {
+    enable = true;
+    device_full = "/sys/class/power_supply/BAT1/charge_full";
+    device_now = "/sys/class/power_supply/BAT1/charge_now";
+  };
+
+  xdg.mimeApps = {
+    enable = true;
+    associations.added."x-scheme-handler/mailto" = ["org.gnome.Evolution.desktop"];
+    defaultApplications."x-scheme-handler/mailto" = ["org.gnome.Evolution.desktop"];
+  };
+}